/*
El ciclo económico en Costa Rica
Este do-file lee datos del Banco Central de Costa Rica que han sido previamente 
almacenados en el archivo de Excel Datos-business-cycle.xlsx, y aplica el filtro 
de Hodrick Prescott para analizar los ciclos.
 
Randall Romero-Aguilar, 2017
Universidad de Costa Rica, Macroeconomía 2
*/




*================================
* PREPARACION

clear all
set more off
cls

* NOTA: Ajustar esta dirección a la que contiene el archivo Excel con los datos
cd "C:\Users\Randall\OneDrive\Documents\Teaching\UCR\EC3201 Macroeconomía 2\Problems"
local FILENAME "Datos-business-cycle.xlsx"



*================================
* DATOS DE CUENTAS NACIONALES

import excel `FILENAME', sheet("chart1677") cellrange(B6:CX16) clear
xpose, clear
keep v1 v3 v5

rename v1 pib
rename v3 c
rename v5 i

gen trimestre = _n + 4*(1991-1960) - 1
tsset trimestre, quarterly
save quiz2_ctas, replace


*================================
* DATOS DE PRECIOS

import excel `FILENAME', sheet("chart2732") cellrange(B5:B325) firstrow clear
rename Nivel ipc
gen mes = _n + 12*(1991-1960) - 1
tsset mes, monthly


gen trimestre = qofd(dofm(mes))
collapse (mean) ipc, by(trimestre)
tsset trimestre, quarterly
save quiz2_precios, replace



*================================
* DATOS DE DINERO

import excel `FILENAME', sheet("chart125") cellrange(B6:M32) clear
xpose, clear
stack v1-v27, into(m1)

gen mes = _n + 12*(1991-1960) - 1
tsset mes, monthly

gen trimestre = qofd(dofm(mes))
collapse (mean) m1, by(trimestre)
tsset trimestre, quarterly
save quiz2_dinero, replace


*================================
* DATOS DE EMPLEO

import excel `FILENAME', sheet("chart1914") cellrange(B6:AC12) clear
xpose, clear
keep v2
rename v2 N

gen trimestre = _n + 4*(2010-1960) + 1
tsset trimestre, quarterly
save quiz2_empleo, replace


*================================
* COMBINAR TODOS LOS DATOS
clear
use quiz2_ctas
merge 1:1 trimestre using quiz2_precios, nogen
merge 1:1 trimestre using quiz2_dinero, nogen
merge 1:1 trimestre using quiz2_empleo, nogen
order trimestre , first

*================================
* CALCULAR EL CICLO DE CADA SERIE,
* USANDO EL FILTRO HODRICK-PRESCOTT

foreach var of varlist pib-N{
	generate temp = log(`var')
	tsfilter hp cycle = temp, smooth(1600)
	drop `var' temp
	rename cycle `var'
	label variable `var' `var'
}

*================================
* GRAFICAR LAS CORRELACIONES

foreach var of varlist c-N{
	tw lfitci `var' pib || scatter `var' pib , ///
	name(g`var') nodraw leg(off) ytitle(`var')
}

graph combine gc gi gipc gm1 gN, cols(3) name(correlaciones)

*================================
* CALCULAR LA CORRELACIÓN DE CICLOS

gen Lpib = L.pib
gen Fpib = F.pib
foreach var of varlist c-N{
	correlate Fpib pib Lpib `var' 
}


*================================
* CALCULAR LA VOLATILIDAD RELATIVA

collapse (sd) pib-N


foreach var of varlist c-N{
	replace `var' = 100 * `var'/ pib
}

list


*================================
* BORRAR LOS ARCHIVOS CREADOS
erase quiz2_ctas.dta
erase quiz2_precios.dta
erase quiz2_dinero.dta
erase quiz2_empleo.dta